VBOffice

Kontakte nach Geburtstag sortieren

Mit diesem Script erstellen Sie eine Geburtstagsliste, die korrekterweise nur nach Tag und Monat sortiert und das Geburtsjahr ignoriert.

Zuletzt geändert: 01.02.2013 | Aufrufe: 34.451  | #96
◀ Vorheriges Beispiel Nächstes Beispiel ▶
Reporter Reporter
Mit dem Reporter erstellen Sie Berichte für Ihre Outlook Daten. Mit wenigen Klicks werden Werte aus Aufgaben, Terminen und dem Journal summiert.

Kontakte können in Outlook nicht sinnvoll nach dem Geburtstag sortiert werden, weil die Jahreszahl auch mitsortiert wird. Bei Geburtstagen interessieren aber nur der Tag und der Monat.

Diese VBA-Funktion fügt einem auszuwählenden Kontakteordner ein neues Feld hinzu und schreibt Monat und Tag des Geburtstags hinein. Damit richtig sortiert wird, muss der Monat vor dem Tag geschrieben werden, also im Format "mm.dd."


tip  So fügen Sie Makros in Outlook ein
Public Sub AddFormattedBirthday()
  Dim Folder As Outlook.MAPIFolder
  Dim Items As Outlook.Items
  Dim UserProps As Outlook.UserProperties
  Dim Prop As Outlook.UserProperty
  Dim obj As Object
  Dim Contact As Outlook.ContactItem
  Dim BDay As Date
  Dim DateFormat$
  Dim Name$

  'Name des neuen Feldes
  Name = "FormattedBirthday"

  'Datumformat
  DateFormat = "mm.dd."

  While Folder Is Nothing
    Set Folder = Application.Session.PickFolder
    If Folder Is Nothing Then Exit Sub
    If Folder.DefaultItemType <> olContactItem Then
      MsgBox "Es werden nur Kontakteordner unterstützt", vbInformation
      Set Folder = Nothing
    End If
  Wend

  Set Items = Folder.Items
  If Items.Count Then
    For Each obj In Items
      If TypeOf obj Is Outlook.ContactItem Then
        Set Contact = obj
        BDay = Contact.Birthday
        If Year(BDay) > 0 And Year(BDay) < 4000 Then
          Set UserProps = Contact.UserProperties
          Set Prop = UserProps.Item(Name)
          If Prop Is Nothing Then
            Set Prop = UserProps.Add(Name, olText, True)
          End If
          Prop.Value = Format(BDay, DateFormat)
          Contact.Save
        End If
      End If
    Next
  End If
End Sub

Category-Manager Category-Manager
Mit dem Category-Manager können Sie Outlook Kategorien gruppieren, synchronisieren und filtern, neuen Emails automatisch die Kategorie des Absenders zuweisen und vieles mehr. Das Addin ist auch für IMAP geeignet.
email  Senden Sie eine Nachricht